Extraer texto entre paréntesis en Excel

En algún momento, nos puede ser útil poder extraer el texto que se encuentre entre paréntesis en una celda de Excel, proceso que se puede automatizar con una serie de fórmulas.

Cómo extraer texto entre paréntesis

Por ejemplo, puede ser el caso en que encontremos lo siguiente:

• Medellín (Antioquia)
• Ibagué (Tolima)
• Girardot (Cundinamarca)
• Cali (Valle), Colombia.

Quizás necesitemos extraer a una celda de Excel únicamente el nombre del departamento que se encuentra entre paréntesis.

Para ello, haremos uso de la siguiente fórmula:

=SI.ERROR(EXTRAE(A1;ENCONTRAR("(";A1)+1;ENCONTRAR(")";A1)-ENCONTRAR("(";A1)-1);"")

Aquí hemos supuesto que los datos están en A1; luego, si están en otra celda, solo habrá que modificarla. Luego se arrastra hacia abajo para las demás celdas.

Lo que hace esta fórmula es extraer lo que encuentre dentro de los paréntesis.

Si queremos extraer incluso los paréntesis, modificamos un poco la fórmula:

=SI.ERROR(EXTRAE(A1;ENCONTRAR("(";A1);ENCONTRAR(")";A1)-ENCONTRAR("(";A1)+1);"")

Nótese que hemos eliminado el +1 que indica el lugar desde donde se debe extraer una vez ubicado el valor de referencia, en este caso el paréntesis que abre “(“, y el -1 del final lo hemos cambiado por +1 para indicar que extraiga incluso el valor de referencia final encontrado “)”.

Este conjunto de fórmulas aplica para extraer cualquier criterio, no solo valores entre paréntesis, sino valores que están después de un guion, por ejemplo, o entre comillas.

Por último, si quisiéramos extraer únicamente la primera parte, palabra o palabras, es decir, todo lo que está antes del paréntesis o del valor que le indiquemos, la fórmula será:

=SI.ERROR(IZQUIERDA(A4;ENCONTRAR("(";A4)-1);A4)

La función SI.ERROR se utiliza para que, cuando no haya que mostrar dentro de los criterios fijados, simplemente nos deje una celda en blanco.

Extraer texto entre comillas

Supongamos que tenemos el siguiente texto entre comillas:

Bogotá "DC"

Para extraer la DC, utilizamos la siguiente fórmula:

=SI.ERROR(EXTRAE(A2;ENCONTRAR("""";A2)+1;ENCONTRAR("""";A2;ENCONTRAR("""";A2)+1)-ENCONTRAR("""";A2)-1);"")

Estas fórmulas se colocan en las celdas en las que se pretende colocar el texto extraído, y luego arrastramos hacia abajo para cubrir todo el rango de datos que necesitamos.

Twitter Facebook WhatsApp LinkedIn